Wer häufig die Nachverfolgungskennzeichnung benötigt, kann sich mit dem folgenden Code das Leben erleichtern und viele Mausklicks sparen.

Zur Verwendung dieses Beispiels beachten Sie bitte die wichtigen Hinweise, sowie den Workshop VBA in Outlook® verwenden.

Option Explicit

Public Sub SetFlag()

    '=====================================================================
    ' Setzt die Nachverfolgungskennzeichnung markierter E-Mails
    ' (c) 2007-2008 Peter Marchert - http://www.outlook-stuff.com
    '=====================================================================

    Dim objMail         As Outlook.MailItem   ' Einzelne E-Mail
    Dim strRequest      As String             ' Text für die Kennzeichnung
    Dim lngFlagColor    As Long               ' Fähnchenfarbe
    Dim lngItem         As Long               ' Schleifenzähler
    Dim lngItems        As Long               ' Anzahl markierter E-Mails

    '---------------------------------------------------------------------
    ' Kennzeichnungstext festlegen
    '---------------------------------------------------------------------
    strRequest = "Wiedervorlage"
    
    '---------------------------------------------------------------------
    ' Fähnchenfarbe festlegen (ab Outlook® 2003)
    ' 1 = Violett; 2 = Orange; 3 = Grün; 4 = Gelb; 5 = Blau; 6 = Rot
    '---------------------------------------------------------------------
    lngFlagColor = 3
    
    '---------------------------------------------------------------------
    ' Anzahl markierte E-Mails feststellen
    '---------------------------------------------------------------------
    lngItems = ActiveExplorer.Selection.Count

    '---------------------------------------------------------------------
    ' E-Mails bearbeiten
    '---------------------------------------------------------------------
    For lngItem = 1 To lngItems
        
        '-----------------------------------------------------------------
        ' E-Mail referenzieren
        '-----------------------------------------------------------------
        Set objMail = ActiveExplorer.Selection(lngItem)
        
        '-----------------------------------------------------------------
        ' Eigenschaften festlegen und E-Mail speichern
        '-----------------------------------------------------------------
        With objMail
            .FlagRequest = strRequest   ' Nachverfolgungstext
            .FlagStatus = olFlagMarked  ' Nachverfolgungsmarkierung
            .FlagIcon = lngFlagColor    ' Fähnchenfarbe (ab Outlook® 2003)
            .Save
        End With
    
        '-----------------------------------------------------------------
        ' Referenz auf E-Mail löschen
        '-----------------------------------------------------------------
        Set objMail = Nothing

    Next
    
End Sub