Datum vor den Betreff einer E-Mail einfügen

Mit diesem Code können Sie per Mausklick das aktuelle Datum oder das Empfangsdatum vor den Betreff einer E-Mail oder eines anderen Outlook®-Elements anfügen.

Zur Verwendung dieses Beispiels beachten Sie bitte die wichtigen Hinweise, sowie den Workshop VBA in Outlook® verwenden. Den Code bitte in ein neues Modul kopieren (Einfügen -> Modul im VBA-Editor).

Für Outlook® 2000, Outlook® 2002, Outlook® 2003, Outlook® 2007, Outlook® 2010

Option Explicit
 
Public Sub InsertDate()
 
    '=====================================================================
    ' Fügt an den Anfang des Betreffs eines Elements das Datum ein.
    ' (c) Peter Marchert - http://www.outlook-stuff.com
    ' 2008-11-09 - Version 1.0.0
    ' 2008-11-21 - Version 1.0.1
    ' 2010-11-17 - Version 1.1.0
    '=====================================================================
 
    Dim objItem As Object     ' Aktuelles Element (geöffnet oder markiert)
    Dim blnDate As Boolean    ' Aktuelles Datum oder Empfangsdatum verwenden
 
    '---------------------------------------------------------------------
    ' Soll das aktuelle Datum verwendet werden?
    ' True = Aktuelles Datum verwenden
    ' False = Empfangsdatum verwenden
    '---------------------------------------------------------------------
    blnDate = True
 
    '---------------------------------------------------------------------
    ' Fehlerbehandlung wegen Set-Anweisungen und ReceivedTime ausschalten
    '---------------------------------------------------------------------
    On Error Resume Next
 
    '---------------------------------------------------------------------
    ' Aktuell geöffnetes Element refernzieren
    '---------------------------------------------------------------------
    Set objItem = Outlook.ActiveInspector.CurrentItem
 
    '---------------------------------------------------------------------
    ' Wenn kein Element geöffnet ist, dann markiertes verwenden
    '---------------------------------------------------------------------
    If objItem Is Nothing Then Set objItem = Outlook.ActiveExplorer.Selection(1)
 
    '---------------------------------------------------------------------
    ' Auch nichts markiert?
    '---------------------------------------------------------------------
    If objItem Is Nothing Then GoTo ExitProc
 
    '---------------------------------------------------------------------
    ' Mit dem Formatbefehl wird das Datum maschinell sortierbar
    '---------------------------------------------------------------------
    If blnDate Then
        objItem.Subject = Format(Date, "yyyy-MM-dd") & " " & objItem.Subject
    Else
        objItem.Subject = Format(objItem.ReceivedTime, "yyyy-MM-dd") & _
            " " & objItem.Subject
    End If
 
    '---------------------------------------------------------------------
    ' Änderung speichern
    '---------------------------------------------------------------------
    objItem.Save
 
ExitProc:
 
    '---------------------------------------------------------------------
    ' Referenz auf Element löschen
    '---------------------------------------------------------------------
    Set objItem = Nothing
 
End Sub