Empfängerabhängige Lesebestätigung

In Outlook® kann man generell eine Lese- bzw. Übermittlungbestätigung anfordern oder auch im Einzelfall in den Optionen einer neuen E-Mail.

Manchmal möchte man aber immer nur an bestimmte Empfänger eine Übermittlungs- und/oder Lesebestätigung senden und vergisst es dann hin und wieder. Mit dem folgenden Code können Sie automatisch eine Lese- und/oder Empfangsbestätigung anfordern. Entweder für einzelne Empfänger oder für ganze Domains.

Bitte beachten Sie auch den Tipp Übermittlungsbestätigung/Lesebestätigung.

Zur Verwendung dieses Beispiels beachten Sie bitte die wichtigen Hinweise, sowie den Workshop VBA in Outlook® verwenden. Den Code bitte in ein neues Modul kopieren (Einfügen -> Modul im VBA-Editor).

Für Outlook® 2000, Outlook® 2002, Outlook® 2003, Outlook® 2007

Option Explicit
 
Public Sub ReadReceiptRequested(ByRef Item As Object)
 
    '=====================================================================
    ' Fordert Emfpängerabhängig Lese- und/oder Empfangsbestätigung an
    ' (c) Peter Marchert - http://www.outlook-stuff.com
    ' 2008-11-23 Version 1.0.0
    '---------------------------------------------------------------------
    ' .OriginatorDeliveryReportRequested = Übermittlungsbestätigung
    ' .ReadReceiptRequested = Lesebestätigung
    '                         (bitte nur bei wichtigen E-Mails anfordern)
    '=====================================================================
 
    '---------------------------------------------------------------------
    ' Nur bei versendeten E-Mails wirksam
    '---------------------------------------------------------------------
    If Item.Class = olMail Then
 
        '-----------------------------------------------------------------
        ' Lese- und/oder Empfangsbestätigung Empfängerabhängig setzen
        '-----------------------------------------------------------------
        Select Case Item.Recipients(1).Address
 
            '-------------------------------------------------------------
            ' Auf einzelne Empfänger prüfen
            '-------------------------------------------------------------
            Case "lager@firma1.de"
                Item.OriginatorDeliveryReportRequested = True
                Item.ReadReceiptRequested = True
 
            Case "versand@frima1.de"
                Item.OriginatorDeliveryReportRequested = True
 
            Case "einkauf@firma1.de"
                Item.ReadReceiptRequested = True
 
            Case Else
 
                '---------------------------------------------------------
                ' Auf ganze E-Mail-Domains prüfen
                ' (kann durch ElseIf beliebig erweitert werden)
                '---------------------------------------------------------
                If InStr(Item.Recipients(1).Address, "@firma2.de") Then
                    Item.OriginatorDeliveryReportRequested = True
 
                ElseIf InStr(Item.Recipients(1).Address, "@firma3.de") Then
                    Item.ReadReceiptRequested = True
 
                Else
                    Item.OriginatorDeliveryReportRequested = True
                    ' Immer Übermittlungsbestätigung anfordern'
 
                End If
 
        End Select
 
    End If
 
End Sub

Der Aufruf erfolgt aus dem Modul DieseOutlookSitzung im Application_ItemSend-Ereignis:

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
 
    '=====================================================================
    ' Diese Prozedur wird unmittelbar vor dem Senden einer E-Mail aufge-
    ' rufen. Ist "Cancel" wahr, wird das Senden der E-Mail abgebrochen.
    ' (c) Peter Marchert - http://www.outlook-stuff.com
    ' 2008-11-23 Version 1.0.0
    '=====================================================================
 
    '---------------------------------------------------------------------
    ' Emfpängerabhängige Lese- und/oder Empfangsbestätigung anfordern
    '---------------------------------------------------------------------
    Call ReadReceiptRequested(Item)
 
    '---------------------------------------------------------------------
    ' Referenz auf E-Mail löschen
    '---------------------------------------------------------------------
    Set Item = Nothing
 
End Sub

Siehe auch Beitrag Funktionen kombinieren