Immer BCC

Zuletzt geändert am 03. April 2013

Manche Anwender möchten, dass alle Ihre E-Mails zusätzlich an eine weitere E-Mailadresse verschickt wird, welche die anderen Empfänger nicht sehen sollen (BCC-Feld).

Dazu können Sie entweder eine entsprechende E-Mailvorlage erstellen oder den folgenden Code benutzen.

Zur Verwendung dieses Beispiels beachten Sie bitte die wichtigen Hinweise, sowie den Workshop VBA in Outlook® verwenden. Den Code bitte in ein neues Modul kopieren (Einfügen -> Modul im VBA-Editor).

Ab Outlook® 2000

Option Explicit
 
Public Function AlwaysBCC(ByRef Item As Object) As Boolean
 
    '=====================================================================
    ' Sendet automatisch bei jeder E-Mail eine Kopie an einen BCC-Empfänger
    ' (c) Peter Marchert - http://www.outlook-stuff.com
    ' 2008-11-23 Version 1.0.0
    '=====================================================================

    Dim objRecipient As Outlook.Recipient   ' (BCC-)Empfänger

    '---------------------------------------------------------------------
    ' Neues Empfängerobjekt erstellen und zur E-Mail hinzufügen
    '---------------------------------------------------------------------
    Set objRecipient = Item.Recipients.Add("postfach@server.de")
 
    '---------------------------------------------------------------------
    ' Der Empfänger ist vom Typ BCC (Blind Carbon Copy)
    '---------------------------------------------------------------------
    objRecipient.Type = olBCC
 
    '---------------------------------------------------------------------
    ' Adresse im Adressbuch auflösen
    '---------------------------------------------------------------------
    objRecipient.Resolve
 
    '---------------------------------------------------------------------
    ' Konnte die Adresse aufgelöst werden?
    '---------------------------------------------------------------------
    AlwaysBCC = IIf(objRecipient.Resolved, False, True)
 
    '---------------------------------------------------------------------
    ' Referenz auf den Empfänger löschen
    '---------------------------------------------------------------------
    Set objRecipient = Nothing
 
End Function

Der Aufruf erfolgt aus dem Modul DieseOutlookSitzung im Application_ItemSend-Ereignis:

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
 
    '=====================================================================
    ' Diese Prozedur wird unmittelbar vor dem Senden einer E-Mail aufge-
    ' rufen. Ist "Cancel" wahr, wird das Senden der E-Mail abgebrochen.
    ' (c) Peter Marchert - http://www.outlook-stuff.com
    ' 2008-11-23 Version 1.0.0
    '=====================================================================
       
    '---------------------------------------------------------------------
    ' Immer die Mail auch an BCC-Empfänger senden
    '---------------------------------------------------------------------
    Cancel = AlwaysBCC(Item)
 
    '---------------------------------------------------------------------
    ' Referenz auf E-Mail löschen
    '---------------------------------------------------------------------
    Set Item = Nothing
 
End Sub

Siehe auch Beitrag Funktionen kombinieren